Schaltjahre in Excel berechnen 3

2 mal 3 Varianten, um in Excel ein Schaltjahr zu ermitteln.
 

Heute ist wieder der besondere Tag, den es nur alle vier Jahre gibt: Der 29. Februar. Wenn auf Deinem Handy (Kalender, Armbanduhr…) also schon der erste März angezeigt, dann hat hier offensichtlich irgendwer ignoriert, dass 2016 ein Schaltjahr ist.

Wie landläufig bekannt ist, finden Schaltjahre nur alle vier Jahre statt. Aber das ist nicht die ganze Wahrheit. Es sind genau genommen 3 Regeln, die bei der Beurteilung eines Schaltjahres zu berücksichtigen sind.

Welche genau das sind und vor allem wie man das in eine schicke Excel-Formel verpackt, erklärt der heutige Artikel.

Und so geht’s:

Wann spricht man von einem Schaltjahr?

Wer es ganz genau wissen möchte, dem sei Wikipedia ans Herz gelegt. Auf den Punkt gebracht, müssen die folgenden Regeln geprüft werden:

Ist die Jahreszahl…

  • …ohne Rest durch 4 teilbar? –> Schaltjahr
  • …ohne Rest durch 100 teilbar? –> kein Schaltjahr
  • …ohne Rest durch 400 teilbar? –> doch wieder ein Schaltjahr

Oder etwas anders formuliert:
Glatte Jahrhunderte (1800, 1900, 2000…) sind demnach Schaltjahre, wenn Sie durch 400 ohne Rest teilbar sind. Somit war 1600 ein Schaltjahr, 1700 jedoch nicht. Alle anderen Jahre sind dann Schaltjahre, wenn sie sich ohne Rest durch 4 teilen lassen.

Und wie berechnet man das jetzt mit Excel? Dazu gibt es die unterschiedlichsten Ansätze. Die Datei mit allen gezeigten Beispielen kannst du bei Bedarf hier herunterladen.

Wenn eine Jahreszahl gegeben ist

Es gibt sicherlich eine Vielzahl an Lösungen für das Schaltjahrproblem. Hier sind drei davon, wenn in einer Zelle lediglich eine Jahreszahl angegeben ist.

Methode 1:
Nehmen wir an, in Zelle B4 befindet sich die Jahreszahl, die wir untersuchen wollen. Mit Hilfe der REST-Funktion und einer WENN-Abfrage lässt sich mit der folgenden Formel bestimmen, ob das angegebene Jahr ein Schaltjahr ist oder nicht:
=WENN((REST(B4;4)=0)-(REST(B4;100)=0)+(REST(B4;400)=0)=0;"kein Schaltjahr";"Schaltjahr")

Methode 1: Jahreszahl + WENN-Funktion

Methode 1: Jahreszahl + WENN-Funktion

Methode 2:
Anstelle der WENN-Funktion kann man auch die WAHL-Funktion nutzen. Außerdem wird zur Abbildung der Regeln eine Kombination aus UND-Funktion und ODER-Funktion verwendet:
=WAHL(ODER(UND(REST(B4;4)=0;REST(B4;100)<>0);REST(B4;400)=0)+1;"kein Schaltjahr";"Schaltjahr")

Methode 2: Jahreszahl + WAHL-Funktion

Methode 2: Jahreszahl + WAHL-Funktion

Methode 3:
Und schließlich noch eine dritte Variante, bei der wir auf die Datumsfunktionen TAG und DATUM zurückgreifen. Hier prüfe ich, ob der 29. ein gültiges Datum ergibt:
=WENN(UND(TAG(DATUM(B4;3;0))=29;B4<>1900);"Schaltjahr";"kein Schaltjahr")
Dabei nutzen wir einen kleinen Trick in der DATUM-Funktion:
DATUM(B4;3;0)
Das wäre also der 0. Tag im März, was dem letzten Tag des Februars gleichkommt.

Außerdem schließe ich im zweiten Teil der UND-Bedingung das Jahr 1900 noch aus, denn für dieses Jahr berechnet die DATUM-Funktion kein korrektes Ergebnis: Excel erlaubt den 29.02.1900 als gültiges Datum, obwohl dieser Tag nicht existiert hat!

Methode 3: Jahreszahl + WENN-Funtion

Methode 3: Jahreszahl + WENN-Funktion

Wichtig: Die letzte Methode funktioniert nur bei einer Jahresangabe ab 1900, denn die Excel-Zeitrechnung – und damit die Datumsfunktionen – beginnt erst am 01.01.1900.

Wenn ein Datum gegeben ist

Liegt hingegen in der Zelle eine beliebige Datumsangabe vor, dann lässt sich mit den folgenden Methoden prüfen, ob es sich um ein Schaltjahr handelt. Es sind vom Ansatz her die gleichen Methoden wie oben, lediglich erweitert um die JAHR-Funktion.

Wichtig: Alle angegebenen Methoden funktionieren nur bei echten Datumsangaben ab dem 01.01.1900, dem Beginn der Excel-Zeitrechnung.

Methode 1:

=WENN((REST(JAHR(B4);4)=0)-(REST(JAHR(B4);100)=0)+(REST(JAHR(B4);400)=0)=0;"kein Schaltjahr";"Schaltjahr")

Methode 1: Datum + WENN-Funktion

Methode 1: Datum + WENN-Funktion

Methode 2:

=WAHL(ODER(UND(REST(JAHR(B4);4)=0;REST(JAHR(B4);100)<>0);REST(JAHR(B4);400)=0)+1;"kein Schaltjahr";"Schaltjahr")

Methode 2: Datum + WAHL-Funktion

Methode 2: Datum + WAHL-Funktion

Methode 3:

=WENN(UND(TAG(DATUM(JAHR(B4);3;0))=29;JAHR(B4)<>1900);"Schaltjahr";"kein Schaltjahr")

Methode 3: Datum + WENN-Funktion

Methode 3: Datum + WENN-Funktion

So, und in 4 Jahren frage ich diese Formeln hier ab!

 

Das könnte dich auch interessieren:

Und immer daran denken: Excel beißt nicht!

P.S. Die Lösung ist immer einfach. Man muss sie nur finden.
(Alexander Solschenizyn)

P.P.S. Das Problem sitzt meistens vor dem Computer.



Kommentar erstellen

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert.

3 Gedanken zu “Schaltjahre in Excel berechnen

  • Gerhard Pundt

    Hallo Martin,
    eine schoene Zusammenstellung hast du uns zum Schaltjahr offeriert.
    Ich moechte noch eine weitere Moeglichkeit drauflegen, ist mir spontan eingefallen:
    Ab A1 schreibe ich die Jahreszahlen, z.B. ab 1985 in die Spalte. In B1 schreibe ich die Formel
    =WENN(DATEDIF(“01.01.”&A1;”31.12.”&A1;”D”)+1=366;”Schaltjahr”;””)
    Die Formel ziehe ich bis unten durch.
    Das sollte so auch gehen.
    Viele Grueße
    Gerhard

  • Detlev

    Hallo Martin und Gerhard,
    eine schöne Formelzusammenstellung von euch beiden zum heutigen “besonderen” Tag. Besonders die DATEDIF ist ein interessanter Tipp!
    Viele Grüße
    Detlev